Le mois dernier je vous ai présenté ma classe d'abstraction pour faire communiquer SAP et Word en utilisant les liens OLE. Bien que j'adore cette méthode pleine de poésie, ce n'est pas très rapide ni pratique pour générer de gros ou nombreux documents. J'ai donc du réfléchir à une autre méthode : créer des fichiers DOCX directement sans utiliser Microsoft.

Afin de pouvoir transformer rapidement mes différents projets clients utilisant l'ancienne classe, j'en ai repris l'interface : les méthodes portent le même nom et utilisent les mêmes paramètres (autant que possible)

Je vous livre donc cette nouvelle classe d'abstraction qui permet de générer un fichier DOCX directement en ABAP. Contrairement aux différents projets balbutiants et aux tutos que j'ai pu voir sur le net, ici la prise en main est ultra simple : un document "hello world" se génère en quelques lignes !

Code pour générer un DOCX Hello World en ABAP

Sont gérés par la classe :

• Création de document vierge ou via template (docx/docm/dotx/dotm)
• Écriture de texte avec ou sans style (style de paragraphe et/ou de police)
• Option bold, italique, souligné, barré, indice, exposant, petite majuscules, choix de police et taille, couleur, surlignage, espacement de caractères
• Gestion de l'alignement, de l'indentation, du retrait, des espaces avant et après le paragraphe, de l'interligne, des bordures de paragraphe et couleur de fond
• Saut de ligne, de page, de section et section continue
• Écriture de tableau avec ou sans style de tableau (et possibilité de définir des option de formatage par cellule : gras, couleur...)
• Écriture d’entête/pied de page simples
• Gestion de l'orientation (portrait/paysage) et des bordures de page
• Insertion d'image
• Insertion de note de bas de page ou de fin de document
• Insertion de commentaires
• Insertion de dessin (canvas)
• Insertion de table des matières
• Insertion de libellés numérotés (figure, table...)
• Insertion de table de libellés (figures, tables...)
• Insertion de propriété de document et de champs personnalisés (custom fields)
• Mise à jour des propriétés de document
• Création de style (caractère, paragraphe)
• Prise en charge des images/templates dans le SAP Web Repository (SAPWR via la stransaction SMW0)
• Pour les utilisateurs avancées ayant des besoins non gérés, possibilité d'inclure un fragment XML de votre composition dans le document en cours

Pour le téléchargement, je livre un programme de démo de la classe qui montre comment l'utiliser. Le zip contient :

• Le package NUGG avec programme de démo et classe dans un "include" séparé
• Un template word et 3 images utilisés par le programme démo
• Un fichier TXT contenant la classe pour ceux qui veulent jeter un oeil au code sans saplink

Prochainement, un cas d'usage sur BW...

Cela fait des années que je pratique cette méthode de communication, pour des petites "bidouilles" entre SAP et Microsoft. C'est rapide et ludique (j'adore voir Word se remplir tout seul, c'est "magique", un peu comme quand je regarde un piano automatique dont les touches s'enfoncent seules lorsqu'il joue).

Enfin rapide... une fois qu'on a réussi a trouver les bonnes commandes ! Car c'est assez galère à programmer :

• commande obscure
• pas ou peu de documentation ou d'exemple
• de nombreuses questions sur le net, mais les réponses sont rares

Cette fois j'ai eu un gros besoin. Je devais générer un document complet, sous word, à partir de tonnes de données SAP. Prenant mon courage à 2 mains, j'ai de nouveau déguainé OLE, et pour que ca soit réutilisable, j'en ai fait une classe d'abstraction.

En utilisant ma classe, fini la galère, vous avez juste a l'inclure en début de votre programme, et ensuite de simples appels aux méthod write_text ou write_table vont vous permettre de remplir votre document... magiquement !

Sont gérés par la classe :

• Création de document vierge ou via template dotx
• Ecriture de texte avec ou sans style (style de paragraphe et/ou de police)
• Option bold, italique, souligné, choix de police et taille, couleur
• Saut de ligne, de page, de section et section continue
• Ecriture de tableau avec ou sans style de tableau (et possibilité de définir des option de formatage par cellule : gras, couleur...)
• Note de bas de page
• Ecriture d'entete/pied de page simples
• Gestion de l'orientation (portrait/paysage)
• Insertion d'image
• Insertion de dessin (canvas)
• Insertion de table des matières
• Insertion de champs personnalisés (custom fields)
• Mise a jour du titre de la fenetre word
• Sauvegarde du document et fermeture de word

A l'usage, je me suis malgré tout rendu compte que la génération était assez longue (5 à 10 minutes pour un document de 50 pages). Ce sont les tableaux qui sont particulièrement lents.

Et donc finalement j'ai du changer de méthode pour mon projet, mais je publie malgré tout cette classe car elle est pleinement fonctionnelle, et pourra toujours vous servir de "how to" sur vos petits besoins OLE :)

Pour le téléchargement, je livre un programme de "test" de la classe qui montre comment l'utiliser. Le zip contient également un template, et quelques images qui sont utilisées par le programme test.

Lassé de créer un écran ne contenant qu'un custom control, avec PBO et PAI rachitiques uniquement pour afficher votre grid ALV objet ? La classe cl_gui_container contient nativement des attributs qui permettent de s'en passer ! Encore faut-il le savoir, ce qui est maintenant votre cas ;-)
En effet, au lieu de créer tout d'abord un objet container puis d'indiquer cet objet en parent de l'objet alv, utilisez directement cl_gui_container=>screen0 comme parent pour votre ALV !

PROGRAM test.
DATA : o_alv      TYPE REF TO cl_gui_alv_grid,
       t_sflight  TYPE TABLE OF sflight.

* Definition d'un écran de sélection vide
SELECTION-SCREEN : BEGIN OF SCREEN 1001,
                   END OF SCREEN 1001.

* Remplissage de la table de données pour l'ALV
SELECT * FROM sflight INTO TABLE t_sflight.

* Creation de l'objet alv directement rattaché au premier screen
CREATE OBJECT o_alv
  EXPORTING
    i_parent = cl_gui_container=>screen0.

* Passage des données a l'ALV
CALL METHOD o_alv->set_table_for_first_display
  EXPORTING
    i_structure_name = 'SFLIGHT'
  CHANGING
    it_outtab        = t_sflight.

* Affichage de l'écran, l'ALV apparait !
CALL SELECTION-SCREEN 1001.

Cette astuce améliore au passage la portabilité de votre code (pas de screen/status/title à gérer).

Derrière ce nom se cache une véritable trousse à outils de méthodes toutes plus utiles les unes que les autres. En effet SAP a décidé de regrouper au sein d'une même classe toutes les "fonctions" de dialogue avec le pc de l'utilisateur (aussi appelé "poste client").
Terminé les WS_UPLOAD ou autre GUI_UPLOAD (que SAP indique depuis longtemps comme obsolète), place à la méthode upload.

L'usage est simplifié au maximum, afin que même les développeurs fermés à l'abap objet puissent les utiliser. Inutile de créer un objet ou déclarer quoi que ce soit, vous pouvez appeler directement la méthode qui vous intéresse dans la classe CL_GUI_FRONTEND_SERVICES, de la même manière que vous appelleriez une fonction classique.

Ci dessous un tableau récapitulant les principales méthodes, avec un exemple d'utilisation.

DATA : s_line(100),
       t_line LIKE TABLE OF s_line,
       i_rc TYPE i.

APPEND 'Test envoi presse-papier' TO t_line.

CALL METHOD cl_gui_frontend_services=>clipboard_export
  IMPORTING
    data         = t_line
  CHANGING
    rc           = i_rc
  EXCEPTIONS
    OTHERS       = 0.
WRITE i_rc.

DATA : s_line(100),
       t_line LIKE TABLE OF s_line,
       i_length TYPE i.

CALL METHOD cl_gui_frontend_services=>clipboard_import
  IMPORTING
    data         = t_line
    length       = i_length
  EXCEPTIONS
    OTHERS       = 0.

LOOP AT t_line INTO s_line.
  WRITE / s_line.
ENDLOOP.

DATA : w_folder TYPE string,
       w_title TYPE string,
       w_init TYPE string.

w_title = 'Rechercher le dossier'.
w_init = 'C:'.

CALL METHOD cl_gui_frontend_services=>directory_browse
  EXPORTING
    window_title    = w_title
    initial_folder  = w_init
  CHANGING
    selected_folder = w_folder
  EXCEPTIONS
    OTHERS          = 0.

WRITE w_folder.

DATA : w_dir TYPE string,
       i_rc TYPE i.

w_dir = 'C:Nouveau Rep inexistant'.

CALL METHOD cl_gui_frontend_services=>directory_create
  EXPORTING
    directory = w_dir
  CHANGING
    rc        = i_rc
  EXCEPTIONS
    OTHERS    = 0.

WRITE i_rc.

DATA : w_dir TYPE string,
       i_rc TYPE i.

w_dir = 'C:Nouveau Rep inexistant'.

CALL METHOD cl_gui_frontend_services=>directory_delete
  EXPORTING
    directory = w_dir
  CHANGING
    rc        = i_rc
  EXCEPTIONS
    OTHERS    = 0.

WRITE i_rc.

DATA : w_dir TYPE string,
       w_rc.

w_dir = 'C:guixt'.

CALL METHOD cl_gui_frontend_services=>directory_exist
  EXPORTING
    directory = w_dir
  RECEIVING
    result    = w_rc
  EXCEPTIONS
    OTHERS    = 0.

WRITE w_rc. "X si existe, space si n'existe pas

DATA : s_line(100),
       t_line LIKE TABLE OF s_line,
       w_dir TYPE string,
       i_count TYPE i.

w_dir = 'C:'.

CALL METHOD cl_gui_frontend_services=>directory_list_files
  EXPORTING
    directory                   = w_dir
    filter                      = '*.TXT'
*    FILES_ONLY                  =
*    DIRECTORIES_ONLY            =
  CHANGING
    file_table                  = t_line
    count                       = i_count
  EXCEPTIONS
    OTHERS                      = 0.

WRITE i_count.
LOOP AT t_line INTO s_line.
  WRITE / s_line.
ENDLOOP.

DATA : w_var TYPE string,
       w_val TYPE string.

w_var = 'OS'.

CALL METHOD cl_gui_frontend_services=>environment_get_variable
  EXPORTING
    variable = w_var
  CHANGING
    value    = w_val
  EXCEPTIONS
    OTHERS   = 0.

WRITE w_val.

DATA : w_var TYPE string,
       w_val TYPE string,
       i_rc TYPE i.

w_var = 'NEWVAR'.
w_val = 'TEST'.
CALL METHOD cl_gui_frontend_services=>environment_set_variable
  EXPORTING
    variable = w_var
    value    = w_val
  CHANGING
    rc       = i_rc
  EXCEPTIONS
    OTHERS   = 0.

WRITE i_rc.

DATA : w_appl TYPE string,
       w_param TYPE string.

w_appl = 'C:WINDOWSNOTEPAD.EXE'.
w_param = 'C:boot.ini'.

CALL METHOD cl_gui_frontend_services=>execute
  EXPORTING
    application            = w_appl
    parameter              = w_param
  EXCEPTIONS
    OTHERS                 = 0.

DATA : w_file TYPE string,
       i_rc TYPE i.

w_file = 'C:test.txt'.

CALL METHOD cl_gui_frontend_services=>file_delete
  EXPORTING
    filename = w_file
  CHANGING
    rc       = i_rc
  EXCEPTIONS
    OTHERS   = 0.

WRITE i_rc.

DATA : w_file TYPE string,
       w_rc.

w_file = 'C:test.txt'.

CALL METHOD cl_gui_frontend_services=>file_exist
  EXPORTING
    file   = w_file
  RECEIVING
    result = w_rc
  EXCEPTIONS
    OTHERS = 0.

WRITE w_rc.

DATA : w_titre TYPE string,
       w_file TYPE string,
       w_dir TYPE string,
       t_file TYPE filetable,
       s_file LIKE LINE OF t_file,
       i_rc TYPE i.

w_titre = 'Selection de fichier'.
w_file = 'test.txt'.
w_dir = 'C:guixt'.

CALL METHOD cl_gui_frontend_services=>file_open_dialog
  EXPORTING
    window_title      = w_titre
    default_filename  = w_file
    initial_directory = w_dir
  CHANGING
    file_table        = t_file
    rc                = i_rc
  EXCEPTIONS
    OTHERS            = 0.

WRITE i_rc.
LOOP AT t_file INTO s_file.
  WRITE / s_file.
ENDLOOP.

DATA : w_titre TYPE string,
       w_file TYPE string,
       w_dir TYPE string,
       w_name TYPE string,
       w_path TYPE string,
       w_fp TYPE string.

w_titre = 'Selection de fichier pour sauvegarde'.
w_file = 'test.txt'.
w_dir = 'C:guixt'.

CALL METHOD cl_gui_frontend_services=>file_save_dialog
  EXPORTING
    window_title      = w_titre
    default_file_name = w_file
    initial_directory = w_dir
  CHANGING
    filename          = w_name
    path              = w_path
    fullpath          = w_fp
  EXCEPTIONS
    OTHERS            = 0.

WRITE : / w_name, / w_path, / w_fp.

DATA : w_file type string,
       s_file type string,
       t_file like table of s_file.

w_file = 'C:test.txt'.
s_file = 'Test de contenu de fichier'.
append s_file to t_file.

CALL METHOD cl_gui_frontend_services=>gui_download
  EXPORTING
    filename                = w_file
    FILETYPE                = 'ASC'
  changing
    data_tab                = t_file
  EXCEPTIONS
    others                  = 0.

DATA : w_file TYPE string,
       s_file TYPE string,
       t_file LIKE TABLE OF s_file.

w_file = 'C:test.txt'.

CALL METHOD cl_gui_frontend_services=>gui_upload
  EXPORTING
    filename = w_file
  CHANGING
    data_tab = t_file
  EXCEPTIONS
    OTHERS   = 0.

LOOP AT t_file INTO s_file.
  WRITE / s_file.
ENDLOOP.